|
동호회 고수님들의 모트스크립트와 레지스트리 팁으로
p100 1년 약정을 무사히 채웠습니다.
그대로 쓴 것도 있고, 나름 수정해서 쓴 것도 있는데요
작은 도움이라도 되길 바라며 모트스크립트 몇 개를 여기 올려 보겠습니다.
1. 화면 밝기 변경
'최대밝기', '최소밝기' 두 개의 스크립트를 쓰는 방법도 있었고
'최대밝기'와 '최소밝기'를 토글하는 하나의 스크립트를 쓰는 방법도 있었습니다.
저는 '최대밝기'로 설정한 후 '조명' 설정을 띄우는 스크립트를 버튼 하나에 매핑해서 썼습니다.
스크립트 실행 후, 실외에서는 조명 설정을 그냥 닫으면 되고,
실내에서는 주위 상황에 맞게 왼쪽 키를 누르고 닫으면 됩니다.
############################
RegWriteDWord("HKLM", "Software\GigabyteCM\LCDBacklight", "BatteryPower", 1023)
Run("\Windows\ctlpnl.exe","cplmain.cpl,6,2")
Exit
############################
2. '네트워크 관리' 띄우기
저는 스마트100 요금을 쓰고 있지만, 주위에 무선랜이 있으면 무선랜부터 접속합니다.
그래서 KTF-HSDPA, 무선랜(집), 무선랜+VPN(회사) 환경을 매번 바꾸며 쓰고 있는데
이 경우 '네트워크 설정'에서 'KTF', 'ISP 설정', '회사 네트워크'를 적절히 선택해 주어야 합니다.
그러기 위해서 우선 '시작'->'설정'->'연결'->'연결'->'고급'->'네트워크 선택'부터
차례로 클릭해야 하는데, 이게 무척이나 성가셔서 이 6번의 클릭을 대신 해 주는 스크립트를 짰습니다.
핵심은 몇 줄 안 되는데, p100이 느려서 예외처리가 필요했습니다.
잘 안되시는 분은 Sleep값을 늘려 보세요.
한글롬 기준이고요, 설정 -> 연결 -> 연결 항목 나오게 하는 레지스트리 세팅부터 되어 있어야 합니다.
(http://www.todaysppc.com/mbzine/bbs/zboard.php?id=gb&no=12586)
###########################
# NOTE: p100
Run("\Windows\ctlpnl.exe","cplmain.cpl,19,0")
Sleep(100)
Run("\Windows\ctlpnl.exe","cplmain.cpl,19,1")
#SendTab("",1,0,0)
Sleep(1500)
SendSpecial("CR")
Sleep(2000)
t = WndExists("네트워크 관리")
count = 1
While(NOT t)
SendSpecial("CR")
Sleep(1000)
t = WndExists("네트워크 관리")
If (count >= 3)
t = 1;
EndIf
count = count + 1
EndWhile
SendTab
SendTab
SendTab
Sleep(100)
SleepMessage(1,"네트워크관리 호출 끝")
###########################
3. cpu profile 설정
'\windows\시작'에 넣어 놓으면, 부팅중에 '성능 모드' 설정을 레지스트리에 write합니다.
스크립트 실행 후, '시작'->'설정'->'시스템'->'CPU 프로필'로 차례로 들어가 보면
'성능 모드'로 되어 있긴 한데 정말로 효과가 있는지는 잘 모르겠습니다.
############################
RegWriteDWord("HKCU", "Software\GigabyteCM\CPUManagement\power saving", "powersaving mode", 0)
RegWriteDWord("HKCU", "Software\GigabyteCM\CPUManagement\standard mode", "standard mode", 0)
RegWriteDWord("HKCU", "Software\GigabyteCM\CPUManagement\performance mode", "performance mode", 1)
#SleepMessage(1,"Performance Mode")
############################
4. 가장 최근 '레코더' 파일 찾아서 들려주기
건망증 해소를 위해 보이스 레코더를 쓰는게 어떨까 하고 p100에 기본 내장된 프로그램 '레코더'를 써 봤는데
파일명이 좀 난해하더군요.
주차를 어디에 했는지 녹음해 놓고, 일 보고 와서 녹음 내용을 듣고 차를 찾는 것처럼 건망증과 관련된 활용에서는,
가장 최근의 녹음내용을 버튼 원터치로 듣는 편이 좋겠다 싶었습니다.
저는 이렇게 활용하고 있습니다.
= 설정 =
가. p100 내장 '레코더'를 '녹음 키(누름)'에 할당
나. 아래의 모트스크립트를 다른 키에 할당
다. sdcard에 백업용 폴더 (\Storage Card\음성녹음) 생성
라. 오른쪽 위의 ok나 'x'를 누르면 프로그램을 완전히 종료시키는 유틸리티 사용(vbar 등등)
= 사용 =
가. 녹음키 눌러서 레코더 실행
나. 레코더 프로그램의 레코드 버튼 눌러서 녹음 후 종료
다. 다른 일...
라. 할당한 키를 눌러 아래 모트스크립트 실행
마. 청취 후 windows media player를 반드시 '종료' (background 실행시 스크립트가 종료되지 않습니다.)
바. 차후 필요시 백업용 폴더에서 파일 선택하여 청취
스크립트 실행 후 volume 아이콘 모양이 바뀌는 경우가 있는데요,
실제로는 스크립트 전의 volume 설정이 그대로 유지됩니다.
######################################################################
searchFile = "\My Documents\내 레코더\voc*.amr"
backupDir = "\Storage Card\음성녹음"
If (NOT DirExists(backupDir))
MkDir(backupDir)
EndIf
maxT = 0
recentFile = ""
ForEach fileName in files (searchFile)
tc = FileCreateTime( fileName )
If ( maxT < tc)
maxT = tc
recentFile = fileName
EndIf
EndForEach
If (maxT > 0)
curVol = Volume()
soundRingTone0 = RegRead("HKCU","ControlPanel\Sounds\RingTone0","Sound")
soundUSSDBuzz = RegRead("HKCU","ControlPanel\Sounds\USSDBuzz","Sound")
mode = RegRead("HKCU","ControlPanel\Notifications\ShellOverrides","Mode")
SetVolume(255 )
RunWait ("\Windows\wmplayer.exe", """" & recentFile & """" )
SetVolume(curVol )
RegWriteString("HKCU","ControlPanel\Sounds\RingTone0","Sound",soundRingTone0)
RegWriteString("HKCU","ControlPanel\Sounds\USSDBuzz","Sound", soundUSSDBuzz )
RegWriteDWord("HKCU","ControlPanel\Notifications\ShellOverrides","Mode",mode)
Move(recentFile, backupDir, TRUE)
Else
SleepMessage(1,"파일이 없습니다.")
Endif
######################################################################
이상입니다.
추천:bycha
추천:
|
