#!-------------------------------
#! 정해진 시간에 자동 리부팅 하기
#!               by shinjinho.com
#!-------------------------------

# Global 상수 정의
TRUE = 1
SCRIPT_NAME = "\Windows\시작\AutoReboot_shin.mscr"
REBOOT_START_HOUR = 16

# 서브루틴 호출
Call rebooting

#!---------------------
#! 리부팅 처리 서브루틴
#!---------------------
Sub rebooting
	 # 변수 정의
	bool_reset = FALSE
	next_time = 0
	now_timestamp = TimeStamp()

	# 현재 시간을 저장
	now_hour   = formattime("H", now_timestamp)
	now_minute = formattime("i", now_timestamp)
	now_second = formattime("s", now_timestamp)

	# 설정 시간인지 확인한다. 바로 리셋 하기 위해서다
	if(now_hour = REBOOT_START_HOUR && now_minute = 0)
		if(now_second <= 10)
			# 리셋모드로 들어온 것으로 파악됨
			# 다음 리셋을 위해 시간을 하루 증가 시킨다
			next_time = 86460
			bool_reset = TRUE
		endif
	endif

	# 설정 시간이 지났다면 내일 날짜로 설정하기 위해 시간을 하루 증가시킨다
	if(now_hour > REBOOT_START_HOUR || (now_hour = REBOOT_START_HOUR && now_minute > 0))
		next_time = 86460
	endif

	# 다음 리셋 시간 을 계산한다
	set_year  = formattime("Y", now_timestamp + next_time)
	set_month = formattime("m", now_timestamp + next_time)
	set_day   = formattime("d", now_timestamp + next_time)

	# 다음 리셋 시간 메시지를 만든다
	str_next_time = FormatTime("다음 자동 리셋 시간은^NL^Y년 m월 d일 "&REBOOT_START_HOUR&"시 입니다.", now_timestamp + next_time)

	# 기존 등록된 예약을 삭제하고 다음 예약을 등록해 놓는다
	RemoveNotifications(SCRIPT_NAME)
	RunAt(set_year, set_month, set_day, REBOOT_START_HOUR, "0", SCRIPT_NAME)

	# 리셋을 결정한다
	if(bool_reset)
		# 리셋 실행
		SleepMessage(10, "잠시 후 자동 리셋을 실행합니다.^NL^"&str_next_time, "자동 리셋 - 알림", TRUE)

		Repeat (3)
			Vibrate( 200 )
			sleep(50)
		EndRepeat

		# 리셋
		Reset
	else 
		# 리셋 설정 알림
		SleepMessage(5, "자동 리셋 을 등록합니다.^NL^"&str_next_time, "자동 리셋 - 알림", TRUE)
	endif
EndSub